TVM Program for the HP-25/25C/33E/33C/10C

Back to main page If this is useful to you, Email me at: Genewright143@hotmail.com

This program will run as written on the machines listed above. It provides a solution to the Time Value of Money situation involving annuities. This program is original with me. It will not solve problems where the interest rate is unknown; there's not enough memory in these models to do that and solve the other pieces at the same time. Also, if you lose a ton of money due to some defect in this program, I am not responsible.

Key in all of these values, using a zero for unknown or not used.

N    STO 1
I    STO 2 (Note: 7% is .07, 8% monthly is .08 / 4 or .02)
1+I  STO 0 (Add one to what you just stored in Memory 2)
PV   STO 3
PMT  STO 4
FV   STO 5

1. Initialize: Key GTO 00, R/S. You will see a value in the display. Do NOT change the stack or do anything else before proceeding with the instructions below. If you do, it won't work.

2. Once you have initialized with step 1,

Given	        Do this
N, I, PMT	To solve for Present Value, Press R/S. 
N, I, PV	To solve for Payment, GTO 17, R/S.
N, I, PMT	To solve for Future Value, GTO 21, R/S.
N, I, FV	To solve for Payment, GTO 26, R/S.
I, PMT, PV	To solve for Number of periods, GTO 32, R/S.
I, PMT, FV	To solve for Number of periods, GTO 32, R/S.

Examples:

1) What is the present value of $100 a month for 100 months at 10% compounded monthly?

100, STO 1; .10, ENTER, 12, /, STO 2; 1, +, STO 0; 100, STO 4; 0, STO 3, STO 5.

Key GTO 00. R/S. See 67.67 in the display. Press R/S. See answer of 6766.78.

2) If you owe $1250 today, what quarterly payment is required to pay off the debt in 3 years at 8%, compounded quarterly?

3 years * 4 quarters per year is 12 quarters. Key 12, STO 1; .08, ENTER, 4, /, STO 2; 1, + STO 0; 1250 STO 3; 0, STO 4, STO 5.

If you just turned on the machine or just finished the first example, you don't need to key GTO 00.

Press R/S. See 10.58 in display. GTO 17. R/S. See answer of 118.20. Payment required per quarter.

3) If you deposit $1000 every six months into a savings account paying 7%, compounded semiannually, what will your account balance be in 20 years?

Key 20, ENTER, 2, *, STO 1; .07, ENTER, 2, /, STO 2; 1, +, STO 0; 1000, STO 4; 0, STO 3, STO 5.

Key GTO 00, if needed (see example 2).

Press R/S. See 21.36 in display. GTO 21, R/S. See answer of 84550.28.

4) Suppose in problem 3, that you wanted to have $100,000 in the account in 20 years, what semiannual deposit would you need to make?

Key 20, ENTER, 2, *, STO 1; .07, ENTER, 2, /, STO 2; 1, +, STO 0; 100000, STO 5; 0, STO 3, STO 4.

Key GTO 00, if needed (see example 2).

Press R/S. See 21.36 in display. GTO 26, R/S. See answer of 1182.73.

5) How many monthly deposits of $100 are required before $50,000 has accumulated in a savings account paying 6%, compounded monthly?

Key .06, ENTER, 12, /, STO 2; 1, +, STO 0; 100, STO 4; 50000, STO 5; 0, STO 3.

Key GTO 00, if needed (see example 2).

Press R/S. See 36.17 in display. GTO 32, R/S. See answer of 251.18 months.

6) If you buy a car for $20,000 and want to pay for it with monthly payments of $300, how many payments will you need to make if the financing interest rate is 9%, compounded monthly?

Key .09, ENTER, 12, /, STO 2; 1, +, STO 0; 20000, STO 3; 300, STO 4; 0, STO 5.

Key GTO 00, if needed (see example 2). Press R/S. See 0 in the display. (This is correct) GTO 32, R/S. See answer of -92.77 months. (Ignore negative sign).

Here's the program:

Step	Key
01	RCL 0
02	RCL 1
03	Y^X
04	STO 7
05	1
06	RCL 0
07	RCL 1
08	CHS
09	Y^X
10	-
11	RCL 2
12	/
13	R/S
14	RCL 4
15	*
16	GTO 00
17	RCL 3
18	/
19	1/X
20	GTO 00
21	RCL 7
22	*
23	RCL 4
24	*
25	GTO 00
26	RCL 7
27	*
28	RCL 5
29	/
30	1/X
31	GTO 00
32	1
33	RCL 2
34	RCL 4
35	/
36	RCL 3
37	X NE 0
38	GTO 44
39	RDN
40	RCL 5
41	*
42	+
43	GTO 46
44	*
45	-
46	LN
47	RCL 0
48	LN
49	/

Visitors since 5/10/97